Weber-Spektrum einer Explosion
Die Schallausbreitung bei einem Knall oder Explosion lässt sich mit einfachen Modellen beschreiben. Die erste Ausbreitung erfolgt ohne Schallwellenausbreitung, da sie mit überschallgeschwindigkeit stattfindet. Beim Ausbreiten verlangsamt sich diese kugelförmige Druckfront. Irgendwann ist Schallgeschwindigketi unterschritten und genau ab diesem Punkt breiten sich Schallwellen aus. Der Radius, den das Schallereignis jetzt hat ist charakteristisch und wird Weber-Radius genannt. Da bis dahin keine akustische Abstrahung erfolgt ist, ist also noch die gesamte Knallenergie innerhalb der Kugel mit dem Weber-Radius. Der Schalldruck bei dem die Druckwelle die Schallgeschwindigkeit unterschreitet ist immer der gleiche. Deshalb kann die Schallausbreitung und das Schallspektrum ab hier genau berechnet werden. Das Weberspektrum ist charakteristisch für Knallereignisse. Es hat ein Maximum das sich mit zunehmender Knallenergie zu tieferen Frequenzen verschiebt und dessen Pegel steigt.
Aus der Treibladungsmasse kann recht einfach auf die Explosionsenergie geschlossen werden, und damit auf den Weberradius. Somit lässt sich das gesamte Ereignis mit einem einzigen Parameter vollständig beschreiben. In der Praxis muss man dann noch Randbedingungen berücksichtigen, wie zum Beispiel von einer Kugel abweichende Ausbreitungsform aufgrund der Bodenreflexion.
Skript-Download#!/usr/bin/gnuplot
# J. Schwender 2017
# Weberleistung in Pa, (14.4 KPa entspricht 177 dB)
Pweber=14400
# Weberradius in m
Rweber=0.0234
# Schallgeschwindigkeit in m/s
c=340.0
alpha(f)=3.0*c/Rweber*sqrt((c/(2.0*pi*f*Rweber))**2.0 + 1.0)
# Betrag der komplexen Funktion nach Weber
p(f)=Pweber/pi * sqrt( (alpha(f)/(alpha(f)**2.0 + (2.0*pi*f)**2.0)**2.0 + 2.0*pi*f/(alpha(f)**2.0 + (2.0*pi*f)**2.0))**2.0 )
# Zusammenhang zwischen Weberradius und der Sprengstoffmasse:
Rw1(m)=m**(1.0/3.0)*2.5
# für TNT ist die spezifische Energie 4.1MJ/Kg, damit ergibt sich der
# Zusammenhang zwischen Weberradius und der Energie:
Rw2(E)=E**(1.0/3.0)/64.0
# Die Anzeige Schalldruck in dB bezogen auf die Hörschwelle
db(x)=log(p(x)/2e-5)*10.0
set terminal pdfcairo size 29.7cm,21cm
set output 'WeberSpektrum.pdf'
set title "Weber Spektrum in Abhängigkeit des Weberradius"
set xrange [20:100000]
set format x "%.0s %cHz"
set decimalsign ','
#set grid
xmin=100
set for [j=0:3] for [i in "2 5"] xtics add (xmin*i*10**j xmin*i*10**j)
set style line 51 dt 3 lc rgb 'blue'
set mytics 2
set grid xtics ytics mxtics mytics ls 51, ls 0
set logscale x
set xlabel "Frequenz in Hz"
set samples 1000
set ytics 10
set size 0.95,0.95
set origin 0.03,0.03
#set key left
#plot db(x) title sprintf("R_w=%2.1f m", Rweber)
set yrange [0:140]
#plot for [r=0:10] Rweber=r*0.1 db(x) title sprintf("R_w=%2.1f m", Rweber)
plot for [Rweber in "0.01 0.1 0.2 0.5 1.0 2.0 5.0 10.0"] db(x) title sprintf("R_w=%s m", Rweber)
#---------------
set title "Weber Spektrum in Abhängigkeit der Knallenergie"
plot for [r=0:4] E=40**r Rweber=Rw2(E) db(x) title sprintf("E=%2.1f J", E)
set size 0.95,0.95
set title "Weber Radius als Funktion der Sprengstoffmasse"
set xrange [0.0001:100]
set yrange [0.1:10]
set xlabel "Masse in Kg"
set format x "%.0s·10^{%T}"
set format y "%.1f m"
set logscale y
plot Rw1(x)
set title "Weber Radius als Funktion der Sprengstoffenergie"
set xlabel "Energie"
set xrange [418:418000000]
set format x "%.0s %cJ"
plot Rw2(x)