#!/usr/bin/gnuplot
#
# Die folgenden Gleichungen pds = f(t) sind aus Glück, Bernd: Zustands- und Stoffwerte,
# VEB Verlag für Bauwesen, Berlin, 2. Auflage, 1991
#
#    Geltungsbereich: -20°C ≤ t < 0,01°C , max. Fehler: 0,00% (?) 
pdsa(t) = 611.0 * exp(-4.909965E-4 + 0.08183197 * t - 5.552967E-4 * t**2 - 2.228376E-5 * t**3 - 6.211808E-7 * t**4 )
#
#    Geltungsbereich: 0,01°C ≤ t < 100°C, max. Fehler: 0,02%
pdsb(t) = 611.0 * exp(-1.91275E-4 + 7.258E-2 * t -2.939E-4 * t**2 + 9.841E-7 * t**3 - 1.92E-9 * t**4 )
#
#    Geltungsbereich: 100°C ≤ t < 200°C , max. Fehler: 0,02%
pdsc(t) = 611.0 * exp( 6E-5 + 7.13274E-2 * t - 2.581631E-4 * t**2 + 6.311955E-7 * t**3 - 7.167112E-10 * t**4 )
#  Zusammengefasst in eine Funktion
psat(t)=t<0 ? pdsa(t) : t<100 ? pdsb(t) : t<200 ? pdsc(t) : 0

BN='SättigungsDampfDruck
PDF=BN.'.pdf'
PNG=BN.'.png'
#
set terminal pdf size 29.7cm,21cm
AusgabeDatei=PDF
set output AusgabeDatei

set border
set key left
set xtics 10
set mytics 10
# Gitterdesign:
set grid xtics ytics mxtics mytics lt 1  lc rgb "#afffaf" lw 1,lt 7  lc rgb "#eeeeee" lw 1

set samples 1000
set lmargin 12; set rmargin 6; set tmargin 5; set bmargin 5
set xrange [-20.0:200.0]
set logscale y
Titel="Sättigungsdruck von Wasserdampf (nach Bernd Glück: Zustands und Stoffwerte, 1991)"
set title Titel font ",20"
set xlabel "Temperatur in °C"
set ylabel "Druck in Pa"
set format y "%.0s %c"
plot psat(x) notitle
set output

set terminal png size 1800,1200
set output PNG
replot