Theraband Charakterisierung mit Messdaten
Theraband Gold ist ein relativ reines Latexprodukt. Die Elastizität lässt sich nur eingeschränkt mit dem Hookschen Gesetz beschreiben. Der Hersteller gibt zwar eine Tabelle mit Werten an, diese enden aber bei einer Dehnung von 3,5 und sehen aus wie Werte für sehr lange Dehnungsdauer. Das genügt nicht für Berechnungen einer Schleuder mit diesem Band. Eine Messung der Kraft über die Dehnung zeigt den Funktionsverlauf. Für eine mathematische Beschreibung dieser Funktion lässt sich diese gut annähern indem diese in drei jeweils lineare Funktionsabschnitte unterteilt. Die Daten werden entsprechend in diese drei Teilbereiche aufgeteilt und mit einer linearen Regression die Gleichungen ermittelt. Diese drei Gleichung lassen sich in Gnuplot relativ einfach in eine einzige Funktion packen.
Das führt zu einer Beschreibung des Verlaufs mit 6 Koeffizienten, der über den gesamten Bereich relativ gut deckungsgleich mit den gemessenen Werten ist. Damit ist es möglich Berechnungen durchzuführen wie zum Beispiel die Berechnung einer Schleuder (Zwille). Dafür das Modell der Cauchy-Elastizität verwendet, obwohl sich deutlich Kriecheigenschaften messen lassen. Aber für die relativ schnelle Betätigung ist das Modell hinreichend genau.
Skriptdatei#!/usr/bin/gnuplot
# Ermittlung der Kraftfunktion aus der Regressionsrechnung einer Messreihe
# Längenmessung mit einfachem Metermassstab, Probestück senkrecht hängend
# mit einer Waagschalenvorrichtung am Ende montiert.
# Gewichte waren Präzisions-Kugellagerkugeln deren Masse bis auf mg genau bestimmt wurde.
# Die Ablesung erfolgte möglichst sofort nach Ausflegen des Gewichts
# Die Regression wurde auf den linearen Bereich beschränkt, der entstehende
# Fehler für kleine Auszuglängen in Kauf genommen.
# Theraband Gold zeigt oberhalb 5,5-facher Dehnung steilen Kraftanstieg
#
Breite=1.11 # Breite des Bandes in cm
#
MESSDATEN1="Theraband-em2-teil1.csv"
MESSDATEN2="Theraband-em2-teil2.csv"
MESSDATEN3="Theraband-em2-teil3.csv"
# Bestimmen der Anzahl der Datenblöcke mittels stats, man könnte auch die Ausgabe nach stdout mit nooutput unterdrücken
set datafile separator " "
#set decimalsign locale # Eingaben und Ausgaben mit lokalisiertem Zahlenschreibweise!
#
# für Label Texte
set style line 40 linetype 0 linecolor rgb 'black'
# Gitterdesign:
set style line 30 linetype 0 linecolor rgb "#000000"
set style line 31 linetype 0 linecolor rgb "#cfffcf"
set grid xtics ytics mxtics mytics lt 1 lc rgb "#afffaf" lw 1,lt 7 lc rgb "#eeeeee" lw 1
#
set terminal pdf size 29.7cm,21cm
set output 'Theraband-em2.pdf'
# Papiergrösse leider in Inch! Der Plot muss etwas verkeinert und verschoben werden damit das nicht bis an den Rand geht
set size 0.95,0.90
set origin 0.03,0.05
set xlabel "Dehnung x/x_0"
set ylabel "Kraft in N pro cm Breite" offset 2,0
set key font ",12"
#
# Titel festlegen
set title "Theraband Kraft pro cm Breite, Probe 11×111 mm², 20 °C" font "(,16)"
#
fa(Dx)=a1+a2*Dx+a3*Dx**2
fit fa(x) MESSDATEN1 using ($2/110):($1*9.81/1000)/Breite via a1,a2,a3
fb(Dx)=b1+b2*Dx
fit fb(x) MESSDATEN2 using ($2/110):($1*9.81/1000)/Breite via b1,b2
fc(Dx)=c1+c2*Dx
fit fc(x) MESSDATEN3 using ($2/110):($1*9.81/1000)/Breite via c1,c2
#
#KraftFit1(X)=a1 + a2*X + a3*X**2
L1=1.6
L2=5.5
KraftFit2(X)=b1 + b2*X
d1=-KraftFit2(L1)/(L1-1)
KraftFit3(X)=c1 + c2*X
KraftFit1(X)=d1 - d1*X
#
set print 'TheraBandKoeffizienten-em2.Gold'
print "a1=",a1
print "a2=",a2
print "a3=",a3
print "b1=",b1
print "b2=",b2
print "c1=",c1
print "c2=",c2
print "L1=",L1
print "L2=",L2
print "d1=",d1
print "BandTyp='Gold'"
load 'TheraBandKoeffizienten-em2.Gold'
#
Kraft(x) = x<L1 ? KraftFit1(x) : x<5.5 ? KraftFit2(x) : KraftFit3(x)
set print
#
set xrange [0:6]
set yrange [0:12]
set samples 500
set key center top
plot \
MESSDATEN1 using ($2/110):($1*9.81/1000)/Breite with linespoints lw 3 title "Theraband Gold 1", \
MESSDATEN2 using ($2/110):($1*9.81/1000)/Breite with linespoints lw 3 title "Theraband Gold 2", \
MESSDATEN3 using ($2/110):($1*9.81/1000)/Breite with linespoints lw 3 title "Theraband Gold 3", \
KraftFit1(x) with lines lw 1 title sprintf("linear Fit F=%2.3f N + %2.3f·x/x_0 + %2.3f·x^2 N",a1,a2,a3), \
KraftFit2(x) with lines lw 1 title sprintf("linear Fit F=%2.3f N + %2.3f·x/x_0 N",b1,b2), \
KraftFit3(x) with lines lw 1 title sprintf("linear Fit F=%2.3f N + %2.3f·x/x_0 N",c1,c2), \
Kraft(x)
#set yrange [-3:15]
unset yrange
set xrange [0:7]
set mxtics 2
set mytics 5
#
i1(x)=d1*x - d1/2*x**2
i2(x)=b1*x + b2/2*x**2
i3(x)=c1*x + c2/2*x**2
Ik1=i1(1)
Ik2=-i2(L1)+i1(L1)-i1(1)
Ik3=-i3(L2)+i2(L2)-i2(L1)+i1(L1)-i1(1)
#
plot i1(x)-Ik1, i2(x)+Ik2, i3(x)+Ik3